Number of posts per week in the whole network - between two dates (including the deleted posts)

0

Please login or register to vote for this query.

(click on this box to dismiss)

MathOverflow

Q&A for professional mathematicians

declare @sql nvarchar(max)

create table #result (site sysname
                    , hostname sysname                    
                    , weekstart date
                    , countall integer
                    , countq integer
                    , counta integer)

select @sql = N'insert into #result' + STRING_AGG(concat(N'
select ''', name ,N''' as site
     , ''',hostname ,N'''
     , DATEADD(dd, -(DATEPART(dw, CreationDate)-1), CAST(CreationDate AS Date))
     , COUNT(p.Id)
     , SUM(case when p.PostTypeId = 1 then 1 else 0 end)
     , SUM(case when p.PostTypeId = 2 then 1 else 0 end)
     from ', quotename(name), N'.dbo.postswithdeleted p
    where (CAST(p.CreationDate AS Date)>= ''##Date1?2022-02-01##'') AND
    (CAST(p.CreationDate AS Date)<= ''##Date2?2022-04-01##'')
    GROUP BY DATEADD(dd, -(DATEPART(dw, CreationDate)-1), CAST(CreationDate AS Date))
'),N' 
union all')
from (select convert(nvarchar(max),name) name
    -- , convert(nvarchar(max),sitename)  sitename
    -- , meta
    -- , domain
     ,  concat( 
        -- based on an idea from Glorfindel 
        -- https://meta.stackexchange.com/a/321181
        (case sitename
        WHEN 'Audio' THEN 'video'
        WHEN 'Beer' THEN 'alcohol'
        WHEN 'CogSci' THEN 'psychology'
        WHEN 'Garage' THEN 'mechanics'
        WHEN 'Health' THEN 'medicalsciences'
        WHEN 'Moderators' THEN 'communitybuilding'
        WHEN 'Photography' THEN 'photo'
        WHEN 'Programmers' THEN 'softwareengineering'
        WHEN 'Vegetarian' THEN 'vegetarianism'
        WHEN 'Writers' THEN 'writing'
        WHEN 'Br' THEN 'pt'
        WHEN 'Mathoverflow' THEN concat((meta+'.'), sitename)
        ELSE case when sitename = domain then null else sitename end
        end +'.')
        , (case 
           when sitename <> 'mathoverflow' then (meta+'.') 
           else null 
           end) 
        , (case 
           when sitename <> 'mathoverflow' then concat((domain + '.'), 'com') 
           else 'net' 
           end)
        ) hostname
from (
select name
, case parsename(name,1) 
  when 'Meta' then parsename(name,2)
  else parsename(name,1) 
  end [sitename]
, case parsename(name,1) 
  when 'Meta' then 'meta'
  else null
  end [meta]
  , coalesce(parsename(name,3), parsename(name,2)) [domain]
from sys.databases
where database_id > 5
-- (name not like '%.Meta' or name = 'StackExchange.Meta')
) dbs
) dbsall

exec (@sql)

select weekstart, 
  SUM (countall) AS [All posts], 
  SUM (countq) AS [Questions],
  SUM (counta) AS [Answers]
from #result
group by weekstart
order by weekstart

Enter Parameters

Options:
Switch to meta site
loading Hold tight while we fetch your results